Comments on: Include All in Array Formulas

By: Pawel

Pawel — Thu, 06 Jan 2011 11:29:00 +0000

Instead of using unnamed ranges like D2:D101 it’s better to use named dynamic ranges. You can substitute D2:D101 with cState where cState is named range =OFFSET(Book3!$D$1,1,0,COUNTA(Book3!$A:$A)-1,1). That makes your formulas easier to read as they are in pure English and you don’t have to worry what happens if your data range extends – especially useful when you get your data range from an external source.

By: fzz

fzz — Tue, 26 May 2009 17:18:00 +0000

AleV - it's the SYNTAX of the RANK function that REQUIRES that its 2nd argument be a range. Nothing to do with formula syntax.

To the general point, if recalc speed were the top priority, wouldn't

=SUM(IF(G3="All",D2:D101=H3,(D2:D101=H3)*(C2:C101=G3))*E2:E101)

be the optimal approach? I'd use SUMPRODUCT myself, something more general like

=SUMPRODUCT(((G3="All")+(C2:C101=G3)>0)*(D2:D101=H3),E2:E101)

In the current inclusive, nonjudgmental, bioengineered age, one may need to allow for All as a possible entry for Sex.

By: AleV

AleV — Tue, 26 May 2009 08:42:00 +0000

Thanks fzz.

I'm just a little bit confused as I used to think that since Named Ranges are essentially (in general array) formulas (as Jhon Walkenbach notes in his books, they are entered by using a "=" sign in the Name Manager, so they ARE actually formulas), then they should not be different from other array formulas you can write (and enter in the Name Manager). Apparently my conclusion is wrong: the RANK function (like sumifs and others) can manage Named Ranges but not arrays.

Thanks again,
AleV

By: fzz

fzz — Tue, 26 May 2009 02:18:00 +0000

AleV, Excel Help has always been wrong about the RANK function. It’s 2nd argument MUST be a range reference; it can’t be an array.

By: AleV

AleV — Mon, 25 May 2009 14:16:00 +0000

Hi Dick,
I have some trouble with array formula and as usual I went on your blog looking for some hint: amazingly enough you are talking about Array Formulas...

Does anybody know about any limitation in using array formulas? As far I can see Excel seems to behave inconsistently (i.e. I'm wrong, but I can't get why): if I type the following (fictious) array formula
=SUM(ROW(1:5))

I get 15

If I type
=COUNT(ROW(1:5))
I get 5 (wow!)

If I type
=VLOOKUP(2,ROW(1:5),1,0)
I get 2 (Great!)

If I type
=rank(1,ROW(1:5),0)
I get an error (!!!???)

The same behaviour occurs when I try to use sumifs countifs and other formulas.

How can you explain this behaviour?

By: Bob Phillips

Bob Phillips — Mon, 25 May 2009 10:35:00 +0000

So do I, but sometimes they are a necessary evil. Sometimes you just have to outsort the data otherwise it errors. Then you have to use IF, there is no other way I can think of.

By: Dick Kusleika

Dick Kusleika — Sun, 24 May 2009 14:52:00 +0000

The plus condition is perfect. I hate IFs in my array formulas.

By: frank

frank — Sat, 23 May 2009 13:36:00 +0000

Another fancy trick. Excel is talented, versatile, powerful, is "younger than I am yet it is more popular, worth more money, has more homes, is touched by more women, and is far better at math." (Mike Rouse on Excel's 21st birthday, 5 Sept 2006).

The beauty of this formula is that it makes quantitative sense of a data set by letting Boolean and numeric values work indiscriminately together.

At least one product sign is essential: {=SUM((D2:D101="NY")*1)} makes sense whereas {=SUM(D2:D101=I12)} doesn't, same for =SUMPRODUCT(...), which makes us think these functions were written for multiple condition scenarios.

By: Bob Phillips

Bob Phillips — Sat, 23 May 2009 13:25:00 +0000

Actually yours can be used in the same way, sans IF,

=SUM(((G3="All")+(C2:C101=G3))*(D2:D101=H3)*(E2:E101))

whiche is 5 characters shorter yet, but still a nasty array formula.

By: Bob Phillips

Bob Phillips — Sat, 23 May 2009 13:22:00 +0000

As ever, you can do a non-array form

=SUMPRODUCT(((G3="All")+(C2:C101=G3))*(D2:D101=H3),E2:E101)

and two whole characters shorter (:-))