Bumping Email

Sometimes I will send an email to someone requesting some information or suggesting some action. Sometimes, they ignore me. Can you believe that? In those cases, I need to resend the message, but with a new, strongly-worded message at the top.

Under the Actions menu, there is a Resend This Message button, which works as advertised.

But it’s not perfect. The original message is still there as the original message, rather than quoted like when I reply to a message. I like to put greater than signs in front of the quoted text when I reply or forward. I specify that under Tools – Options – Email Options

What I really want to do, and what I’ve been doing manually, is a Reply to All and remove my email address. That gives me just the behavior I want. Well, no more manually doing that for me!

Public Sub BumpEmail()
   
    Dim miExist As MailItem
    Dim miReply As MailItem
    Dim rcp As Recipient
   
    On Error Resume Next
        Set miExist = Application.ActiveExplorer.Selection.Item(1)
    On Error GoTo 0
   
    If Not miExist Is Nothing Then
        Set miReply = miExist.ReplyAll
        For Each rcp In miReply.Recipients
            If IsMe(rcp.Address) Then
                miReply.Recipients.Remove rcp.Index
            End If
        Next rcp
        miReply.Display
    End If
   
End Sub

And the IsMe function to cover all my email addresses – obfuscated for your enjoyment.

Public Function IsMe(sAddress As String) As Boolean
 
    Dim vaMyEmail As Variant
    Dim i As Long
   
    vaMyEmail = Array(“|me@gmail.com|”, “|me@yahoo.com|”)
   
    IsMe = (UBound(Filter(vaMyEmail, “|” & sAddress & “|”, True)) > -1)
   
End Function

I use the pipes around my email address to force the Filter function to find an exact match inside the array, rather than the partial matches that it finds by default.

The verb ‘bump’ in this context comes from forums. Some forums list the posts with the most recent activity at the top. If someone thinks their post is being ignored, they will reply to their own post with the word ‘bump’, giving their post the appearance of recent activity.

Posted in Uncategorized

4 thoughts on “Bumping Email

  1. Why not just resend the message, and add your text at the top? Or even better, update the subject line. I prefer to resend, in case the recipient doesn’t have the original, they won’t end up with double greater-than signs ‘>’ around the “original” message.

  2. Alternative

    Public Function IsMe(sAddress As String) As Boolean
      IsMe = instr(“|me@gmail.com|me@yahoo.com|”,“|” & sAddress & “|”)>0    
    End Function


Posting code? Use <pre> tags for VBA and <code> tags for inline.

Leave a Reply

Your email address will not be published.