Comments on: My own Euler problem

By: Jan Karel Pieterse

Jan Karel Pieterse — Sun, 01 Mar 2009 11:51:00 +0000

Hi Dan,

I have three textboxes with filter criteria and a table in variant mvTable:
The result is shown in listbox lbxTable.

Sub SetFilter()
Dim lRow As Long
Dim lCol As Long
Dim lFilterColumn As Long
Dim sStr As String
Dim vNewList() As Variant
Dim lRowCt As Long
Dim sFilter1 As String
Dim sFilter2 As String
Dim sFilter3 As String
Application.Cursor = xlWait
On Error Resume Next
lbxTable.Clear
ReDim vNewList(UBound(mvTable, 1), UBound(mvTable, 2))
sFilter1 = LCase(tbxSearchArticle1.Value)
sFilter2 = LCase(tbxSearchArticle2.Value)
sFilter3 = LCase(tbxSearchArticle3.Value)
If Len(sFilter1) + Len(sFilter2) + Len(sFilter3) = 0 Then
lbxTable.List = mvTable
Else
For lRow = 1 To UBound(mvTable, 1)
If (InStr(LCase(mvTable(lRow, 1)), sFilter1) * Len(sFilter1) + _
InStr(LCase(mvTable(lRow, 2)), sFilter2) * Len(sFilter2) + _
InStr(LCase(mvTable(lRow, 3)), sFilter3) * Len(sFilter3)) > 0 Or lRow = 1 Then
For lCol = 0 To UBound(mvTable, 2)
vNewList(lRowCt, lCol) = mvTable(lRow, lCol + 1)
Next
lRowCt = lRowCt + 1
End If
Next
lbxTable.List = vNewList
End If
Application.Cursor = xlDefault
End Sub

By: Dan Randles

Dan Randles — Thu, 26 Feb 2009 21:10:00 +0000

"I filter the array in code, not by using Excel, so no problems with discontinuous ranges."

How JKP?

Do you loop over the array and check items?

By: Jan Karel Pieterse

Jan Karel Pieterse — Thu, 26 Feb 2009 11:35:00 +0000

I filter the array in code, not by using Excel, so no problems with discontinuous ranges.

By: Dan Randles

Dan Randles — Thu, 26 Feb 2009 09:32:00 +0000

"Load table (on sheet) in Variant, pass variant to listbox. Then when filtering is needed, create extra variant array that holds the filtered items and pass that into the listbox. Very fast!"

I've tried this and can't seem to get it to work....

I think the problem is that the variant array represents a non-contiguous group of cells (ie the filtered list). So when filtering on ItemA (of which there are 4 in the list) only one appears in the list box.

I've developed a work around which involves copying the filtered list (ie visible cells) to another sheet and then using this list (which is now contiguous) to populate the listbox.

It works but doesn't feel right...any views?

By: Jon Peltier

Jon Peltier — Wed, 18 Feb 2009 15:31:00 +0000

Jan Karel -

I use pretty much the same approach. Fast to implement, fast to run.

By: Jan Karel Pieterse

Jan Karel Pieterse — Tue, 17 Feb 2009 18:54:00 +0000

Thanks for all the tips guys, keep em coming!
My current method is:

Load table (on sheet) in Variant, pass variant to listbox. Then when filtering is needed, create extra variant array that holds the filtered items and pass that into the listbox. Very fast!

By: sam

sam — Tue, 17 Feb 2009 18:01:00 +0000

I use a Dynamic name(s) for the column(s) that I want to load in a Combobox/Listbox.
On the Properties – Rowsource/ListFillRange – I type the name of the Range

By: Finch

Finch — Tue, 17 Feb 2009 16:31:00 +0000

Reading this blog for some time now, but this is my first reply. I hope it's useful.

I had a similary problem. In my problem the data that needs to be put in the listbox also resides in a worksheet. I did the following:
Put the range of the listbox items in a variant variable and passed them to the list property of the listbox all in once. (like keepITcool stated).

To filter the list in the listbox, I used standard Excel filter options (autofilter) to filter the list on the worksheet. In a next step I copied the filtered rows (using specialcells(xlcelltypevisible)) to a new worksheet. This new sheet (or another range on the data sheet-if you want to skip a sheet) now holds the filtered items with no blank lines. This contiguous range can be put in a variant variable, and populate the listbox as described above very quickly.

I' m aware this method involves some extra steps, but the data is always addressed in block, and not on an item level.

By: Ross

Ross — Tue, 17 Feb 2009 16:21:00 +0000

pass the filter options to a worksheet, and then load the list box from the results, that's how I've done it before.

Alex,
I believe that Bubble Sorts are quite slow in VBA.

By: Jan Karel Pieterse

Jan Karel Pieterse — Tue, 17 Feb 2009 16:15:00 +0000

OK, I cracked it.

I used to have a filtering routine (inside a loop which does all rows) with a test for validity that looked like this:

If LCase(Table(lRow, 1)) Like "*" & LCase(tbxSearchArticle1.Value) & "*" _
And LCase(Table(lRow, 2)) Like "*" & LCase(tbxSearchArticle2.Value) & "*" _
And LCase(Table(lRow, 3)) Like "*" & LCase(tbxSearchArticle3.Value) & "*" Then

I decided to move the calls to the controls out of the loop and use variables. Also I decided to use the module level variable mvTable, rather than the property calls to the Table property Get methods. Finally instead of using Like, I use Instr. So my test changed to:

If (InStr(LCase(mvTable(lRow, 1)), sFilter1) * Len(sFilter1) + _
InStr(LCase(mvTable(lRow, 2)), sFilter2) * Len(sFilter2) + _
InStr(LCase(mvTable(lRow, 3)), sFilter3) * Len(sFilter3)) > 0 Then

Also I used the tip KeepItCool gave to place the array into the listbox directly, which saved me another 0.2 secs.