Comments on: Double Clicking Through a List

By: sam

sam — Fri, 09 May 2008 07:20:00 +0000

"P.S. Why is Target.Validation always something (that is, Not Nothing) even if the cell doesn't have validation?"

All cells in Excel are validated but with a validation type called "Any Value"

By: Rob van Gelder

Rob van Gelder — Thu, 08 May 2008 05:55:00 +0000

Since this is code critic, I'd just like to point out you cannot use "Not Nothing" in code. It would result in a compilation error.

' This will not compile
If obj Is Not Nothing Then MsgBox "Hi"

' This will compile
If Not obj Is Nothing Then MsgBox "Hi"

By: Roger Govier

Roger Govier — Wed, 07 May 2008 17:48:00 +0000

Great idea Dick, and nice amendment from Andy.
this is very useful and something I will definitely make use of.
Perfect for selecting/switching VAT codes on financial sheets.

By: Alex J

Alex J — Wed, 07 May 2008 12:44:00 +0000

Very Nice, Andy. (You too Dick!)I’m going to drop this in my code today.
Just one wrinkle for me: when I used a validation of True,False with direct entry, the “oldValue” variable was type boolean, and the match function failed against the “VaList” values of “True” and “False”. I modified “oldValue” to type String, and it worked, but I’m not sure that this will work in all cases.

By: Peder Schmedling

Peder Schmedling — Wed, 07 May 2008 11:29:00 +0000

After replacing the occurrences of ">" with ">" this works flawlessly.

Nice one with the "Application.International(xlListSeparator)", much sleeker than the method I posted.

By: Andy Pope

Andy Pope — Wed, 07 May 2008 09:38:00 +0000

This variation of your code uses the MATCH function instead of looping through the items.

If the users double clicks anything other than a range I don't believe the worksheet event will be fired.

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)

Dim vaList As Variant
Dim lngIndex As Long
Dim vOldValue As Variant

On Error GoTo ErrDoubleClick

With Target
If .Validation.Type = xlValidateList Then
If Len(Target.Validation.Formula1) > 0 Then 'only if the cell has dv
Cancel = True 'don't do the default action
vOldValue = Target.Value
vaList = GetValidList(.Validation.Formula1) 'return single dim array
If Len(vOldValue) > 0 Then
lngIndex = Application.WorksheetFunction.Match(vOldValue, vaList, 0)
If lngIndex > UBound(vaList) Then lngIndex = LBound(vaList) ' return first item
End If
Target.Value = vaList(lngIndex)
End If
End If
End With

ErrDoubleClick:
Exit Sub

End Sub

Private Function GetValidList(sForm As String) As Variant

Dim vArr As Variant
Dim vaReturn As Variant
Dim lngIndex As Long

If Left(sForm, 1) = "=" Then
' range/named range
vArr = Evaluate(sForm)
ReDim vaReturn(0 To UBound(vArr) - 1)
For lngIndex = LBound(vaReturn) To UBound(vaReturn)
vaReturn(lngIndex) = vArr(lngIndex + 1, 1)
Next
Else
'for csv list
vaReturn = Split(sForm, Application.International(xlListSeparator))
End If
GetValidList = vaReturn

End Function

By: Peder Schmedling

Peder Schmedling — Wed, 07 May 2008 08:46:00 +0000

Hi Dick,
great piece of code you have there. I can confirm the international issue you suspected; I'm using Excel 2003 on a machine set up with Norwegian settings in the control panel. In Norwegian we are using ";" as list separator, not the regular comma. This yields some problems. If I define the list with ";" the Excel data validation works fine, but your code interprets the validation formula as just one entry. The other way around, defining the list with "," yields the opposite results; Excel interprets the validation as a single item while your code treats it as several entries. This behavior is logical an actually expected if you think about it.

In this thread a method is described for obtaining the list separator. Using this method in conjunction with your code seems to work well on my system (Win2k).

You could also read out the sList value from "HKEY_CURRENT_USERControl PanelInternational" in the registry.